#38 Cómo usar do file en STATA​: Análisis del registro de casos del CEM, Programa Nacional Aurora, MIMP

Hola a tod@s, en este video exploro el Portal Estadístico del Programa Nacional AURORA y analizo el registro de casos del Centro de Emergencia Mujer (CEM) con el Stata 15.

El Portal estadístico del Programa Nacional AURORA analiza y difunde información sobre la violencia contra las mujeres e integrantes del grupo familiar, cuya fuente de información son los registros administrativos de los servicios que brinda el Programa Nacional AURORA. 

Bases de datos disponibles:
Base de datos del registro de casos del Centro Emergencia Mujer.
Base de datos del registro de casos Sección E del Centro Emergencia Mujer.
Base de datos del registro de casos (Legal sección F) del Centro Emergencia Mujer.
Base de datos del registro de Acciones Preventivas Promocionales.
Base de datos del registro de casos del Centro de Atención Institucional (CAI).
Base de datos del registro de casos del  Servicio de atención Urgente (SAU).
Base de datos del registro de casos de Consultas Telefónicas – Línea 100.
Base de datos del registro de casos de Estrategia Rural. 
Página web: https://portalestadistico.pe/

********************************************

*Bajar Base de datos del registro de casos del Centro Emergencia Mujer. Año 2019

*Importar el archivo en SPSS a STATA

usespss  "D:\CEM\BD Registro de Casos del CEM 2019.sav", clear

save     "D:\CEM\BD Registro de Casos del CEM 2019.dta", replace

use  "D:\CEM\BD Registro de Casos del CEM 2019.dta", clear

*Casos atendidos en los CEM 

*Grupos de edad

gen     gedad=1 if EDAD_VICTIMA<18

replace gedad=2 if EDAD_VICTIMA>17 & EDAD_VICTIMA<60

replace gedad=3 if EDAD_VICTIMA>59

label define gedad 1 "0 a 17 años" 2 "18 a 59 años" 3 "60 a más años"

label values gedad gedad

gen     gedad_1=1 if EDAD_VICTIMA<6

replace gedad_1=2 if EDAD_VICTIMA>5 & EDAD_VICTIMA<12

replace gedad_1=3 if EDAD_VICTIMA>11 & EDAD_VICTIMA<18

label define gedad_1 1 "0 a 5 años" 2 "6 a 11 años" 3 "12 a 17 años"

label values gedad_1 gedad_1

gen     gedad_2=1 if EDAD_VICTIMA>17 & EDAD_VICTIMA<26

replace gedad_2=2 if EDAD_VICTIMA>25 & EDAD_VICTIMA<36

replace gedad_2=3 if EDAD_VICTIMA>35 & EDAD_VICTIMA<46

replace gedad_2=4 if EDAD_VICTIMA>45 & EDAD_VICTIMA<60

label define gedad_2 1 "18 a 25 años" 2 "26 a 35 años" ///

3 "36 a 45 años" 4 "46 a 59 años"

label values gedad_2 gedad_2

**Tipos de violencia (TIPO_VIOLENCIA)

*Violencia Económica - Patrimonial

*Violencia Psicológica 

*Violencia Física

*Violencia Sexual

label define t_vio 0 "V. Económica" 1 "V. Psicológica" 2 "V. Física" 3 "V. Sexual"

label values TIPO_VIOLENCIA t_vio

**Violaciones sexuales

replace VIOLACION=0 if TIPO_VIOLENCIA==3 & VIOLACION==.

**Vínculo relacional de pareja, familiar u otro que tiene la presunta

*persona agresora con la persona usuaria (VINCULO_AGRESOR_VICTIMA)   

*-Con vínculo relacional de pareja (VINCULO_PAREJA)

*-Con vínculo relacional familiar (VINCULO_FAMILIAR)

*-Sin vínculo relacional de pareja ni familiar (SIN_VINCULO)

*Vamos a agrupar todas estas categorias en una variable "agresor"

gen          agresor=VINCULO_FAMILIAR    if VINCULO_AGRESOR_VICTIMA==2

replace      agresor=VINCULO_PAREJA + 20 if VINCULO_AGRESOR_VICTIMA==1

replace      agresor=SIN_VINCULO    + 30 if VINCULO_AGRESOR_VICTIMA==3

label copy VINCULO_FAMILIAR agresor

label define agresor 21 "Cónyuge" 22 "Ex cónyuge" 23 "Conviviente" /// 

24 "Ex conviviente" 25 "Enamorado/a" 26 "Ex enamorado/a" 27 "Novio/a" /// 

28 "Ex novio/a" 29 "Progenitor/a de su hijo/a" 31 "Vecino/a" 32 "Concuñado/a" /// 

33 "Docente" 34 "Compañero/a de estudios" 35 "Empleador/a de trabajo" ///

36 "Compañero/a de trabajo" 37 "Empleado/a de trabajo" 38 "Otro"  /// 

39 "Habita en el mismo hogar" 40 "Desconocido/a", add

label values agresor agresor

*Violencia según sexo

tab  gedad SEXO_VICTIMA,  row col

tab  gedad TIPO_VIOLENCIA,  row col

tab  gedad VIOLACION,  row col

*Niñas, niños y adolescentes (0 a 17 años)

tab  TIPO_VIOLENCIA gedad_1, col

tab  agresor gedad_1 if TIPO_VIOLENCIA==3

tab  agresor gedad_1 if TIPO_VIOLENCIA==3, nofreq col

*Personas adultas (18 a 59 años)

tab  TIPO_VIOLENCIA SEXO_VICTIMA if gedad==2, row

tab  TIPO_VIOLENCIA gedad_2, col

*Personas adultas mayores (60 a más años)

tab  TIPO_VIOLENCIA SEXO_VICTIMA if gedad==3, row

tab  agresor TIPO_VIOLENCIA if gedad==3

tab  agresor TIPO_VIOLENCIA if gedad==3, nofreq col