Hola a tod@s, en este video comparto la sintaxis para la construcción de indicadores sociales, puntualmente, cómo estimar la cobertura de parto institucional usando la Encuesta Demográfica y de Salud Familiar (ENDES -DHS en inglés) del 2017 en el programa STATA 15.
*****************
/* INDICADOR: Parto Institucional
JUSTIFICACIÓN
Este indicador es una medida del potencial del sistema de salud para proveer una cobertura adecuada para
los partos y da información sobre la cobertura de los partos asistidos, ya sean normales o complejos.
A diferencia de otros indicadores complementarios como la proporción de nacidos vivos atendidos en
establecimientos de salud, este indicador recoge las condiciones en términos de la infraestructura donde se
llevan a cabo los partos, sino también las características de los recursos humanos encargados de llevar a
cabo dichas tareas.
PROPORCIÓN DE PARTOS INSTITUCIONALES DEL ÚLTIMO NACIMIENTO DE LOS CINCO AÑOS ANTERIORES A LA ENCUESTA
Es el porcentaje de mujeres cuya última hija/o nacido vivo en los cinco años anteriores a la encuesta ocurrió en un establecimiento de salud y fue atendido por un médico, obstetra y/o enfermera.
Factor Mujer (V005)
Este factor permite recomponer la estructura poblacional de las mujeres en edad fértil y está ajustado a la no respuesta, se utiliza para el cálculo de indicadores relacionados con esta población, por ejemplo: Planificación familiar de mujeres en edad fértil, parto institucional, demanda insatisfecha de planificación familiar, control prenatal, entre otros. En la base de datos ENDES-2017 se encuentra en el módulo REC0111.
M3A Assistance: doctor
M3B Assistance: nurse/midwife
M3C Assistance: obstetrician
M3N Assistance: no one
M15 Place of delivery
10 HOMES
11 Respondents home
12 Midwife's home
21 Hospital MINSA
22 Hospital ESSALUD
23 Hospital FF. AA. PNP
24 Health center MINSA
25 Health post MINSA
26 Center/Post ESSALUD
27 Local Government
31 Private clinic
32 Private doctor
41 Clinic/Post NGO
42 Church
96 OTHER
98 DK
99 Missing
(na) NotAppl
*/
cd "D:\ENDES"
*Year: 2017
*Bajar los modulos 66, 67 & 69
copy "http://iinei.inei.gob.pe/iinei/srienaho/descarga/DBF/605-Modulo66.zip" 605-Modulo66.zip, replace
unzipfile 605-Modulo66.zip, replace
copy "http://iinei.inei.gob.pe/iinei/srienaho/descarga/DBF/605-Modulo67.zip" 605-Modulo67.zip, replace
unzipfile 605-Modulo67.zip, replace
copy "http://iinei.inei.gob.pe/iinei/srienaho/descarga/DBF/605-Modulo69.zip" 605-Modulo69.zip, replace
unzipfile 605-Modulo69.zip, replace
*Importar los archivos a Stata
import dbase 605-Modulo66\rec0111.dbf, clear
sort CASEID
save 605-Modulo66\rec0111.dta, replace
import dbase Modulo67\rec21.dbf, clear
rename BIDX MIDX
sort CASEID MIDX
save Modulo67\rec21.dta, replace
import dbase 605-Modulo66\rec91.dbf, clear
sort CASEID
save 605-Modulo66\rec91.dta, replace
import dbase Modulo69\rec41.dbf, clear
sort CASEID MIDX
save Modulo69\rec41.dta, replace
*Juntar los archivos
use Modulo69\rec41.dta, clear
merge m:1 CASEID using 605-Modulo66\rec0111.dta
rename _m m1
merge 1:1 CASEID MIDX using Modulo67\rec21.dta
rename _m m2
merge m:1 CASEID using 605-Modulo66\rec91.dta
rename _m m3
save rec41_rec0111_rec21_rec91.dta, replace
use rec41_rec0111_rec21_rec91.dta, clear
*Generamos la variable peso
gen peso=V005/1000000
*Etiquetando la región natural
label define SREGION 1 "Lima Metropolitana" 2 "Resto Costa" 3 "Sierra" 4 "Selva"
label values SREGION SREGION
label var SREGION "Region Natural"
label define V025 1 "Urbano" 2 "Rural"
label values V025 V025
*Generando la variable "parto institucional"
*Parto en establecimiento de salud
recode M15 (21 22 23 24 25 26 27 31 32 41 42=1) (11 12 13 96=2), gen(parto_establ)
label define parto_establ 1 "Si" 2 "No"
label values parto_establ parto_establ
label var parto_establ "Parto en establecimiento de salud"
*Parto atendido por profesional de Salud
gen parto_pers=2 if M3N==0 | M3N==1
replace parto_pers=1 if M3A==1 | M3B==1 | M3C==1
label define parto_pers 1 "Pers Salud" 2 "Otro- Nadie"
label values parto_pers parto_pers
label var parto_pers "Parto atendido por prof salud"
*Parto institucional
recode parto_establ (2 1 = 2), gen(parto_institucional)
replace parto_institucional=1 if parto_establ==1 & parto_pers==1
label define parto_institucional 1 "Si" 2 "No"
label values parto_institucional parto_institucional
label var parto_institucional "Parto en Establecimiento y atendido por prof. de salud"
* Establecemos el diseño muestral: usando las variables factor de expansion, comglomerado y estrato
*****************
svyset V001 [w=peso], strata(V022)
* Vemos los descriptivos de la variable pobre tomando en cuenta el diseño muestral
*****************
svy: proportion M3A
svy: proportion M3B
svy: proportion M3C
svy: proportion parto_pers
svy: proportion parto_pers if MIDX==1
svy: proportion parto_institucional if MIDX==1
svy, over(V025): proportion parto_institucional if MIDX==1
svy, over(SREGION): proportion parto_institucional if MIDX==1
Comentarios
Publicar un comentario