Hola a tod@s,
les comparto la sintaxis que utilice en el video. Si desean la version completa de este do-file, asi como de otros ejercicios en Stata desarrollados por el profesor Oscar Torres-Reyna, chequeen los links de su curso.
Un abrazo,
Un abrazo,
Janet
*=====================================*
* Intro to data visualization * Introduccion a visualizacion de informacion
* Oscar Torres-Reyna *
* DSS Princeton University *
* http://dss.princeton.edu/ *
* https://dss.princeton.edu/training/ *
* https://dss.princeton.edu/training/Visual101.pdf*
*=====================================*
*Especificamos nuestra carpeta de trabajo
cd "D:\OTORRES"
use "https://www.princeton.edu/~otorres/wdipol.dta", clear
*https://databank.bancomundial.org/home.aspx
*https://competitivite.ferdi.fr/en/indicators/polity2-polity-iv
*http://www.systemicpeace.org/polity/polity4.htm
label var year "Año"
label var country "País"
label var gdppc "PBI pc, PPA ($ a precios internacionales constantes de 2005)"
label var unempf "Desempleo, mujeres (% de parti. femenina en la fuerza laboral)"
label var unempm "Desempleo, varones (% de parti. masculina en la fuerza laboral)"
label var unemp "Desempleo, total (% de parti. en la fuerza laboral)"
label var export "Exportaciones de bs y ss (US$ a precios constantes de 2005)"
label var import "Importaciones de bs y ss (US$ a precios constantes de 2005)"
*=====================================*
* Intro to data visualization * Introduccion a visualizacion de informacion
* Oscar Torres-Reyna *
* DSS Princeton University *
* http://dss.princeton.edu/ *
* https://dss.princeton.edu/training/ *
* https://dss.princeton.edu/training/Visual101.pdf*
*=====================================*
*Especificamos nuestra carpeta de trabajo
cd "D:\OTORRES"
use "https://www.princeton.edu/~otorres/wdipol.dta", clear
*https://databank.bancomundial.org/home.aspx
*https://competitivite.ferdi.fr/en/indicators/polity2-polity-iv
*http://www.systemicpeace.org/polity/polity4.htm
label var year "Año"
label var country "País"
label var gdppc "PBI pc, PPA ($ a precios internacionales constantes de 2005)"
label var unempf "Desempleo, mujeres (% de parti. femenina en la fuerza laboral)"
label var unempm "Desempleo, varones (% de parti. masculina en la fuerza laboral)"
label var unemp "Desempleo, total (% de parti. en la fuerza laboral)"
label var export "Exportaciones de bs y ss (US$ a precios constantes de 2005)"
label var import "Importaciones de bs y ss (US$ a precios constantes de 2005)"
/* CONCEPTOS
gdppc: PIB per cápita por paridad del poder adquisitivo (PPA).
El PIB por paridad del poder adquisitivo (PPA) es el producto interno bruto
convertido a dólares internacionales utilizando las tasas de paridad del poder adquisitivo.
Un dólar internacional tiene el mismo poder adquisitivo sobre el PIB que el que
posee el dólar de los Estados Unidos en ese país.
El PIB a precio de comprador es la suma del valor agregado bruto de todos los
productores residentes en la economía más todo impuesto a los productos,
menos todo subsidio no incluido en el valor de los productos.
Se calcula sin hacer deducciones por depreciación de bienes manufacturados
o por agotamiento y degradación de recursos naturales.
Los datos se expresan en dólares internacionales a precios constantes de 2005.
export: Las exportaciones de bienes y servicios representan el valor de todos
los bienes y demás servicios de mercado prestados al resto del mundo.
Incluyen el valor de las mercaderías, fletes, seguros, transporte, viajes,
regalías, tarifas de licencia y otros servicios tales como los relativos a las
comunicaciones, la construcción, los servicios financieros, los informativos,
los empresariales, los personales y los del Gobierno.
Excluyen la remuneración de los empleados y los ingresos por inversiones
(anteriormente denominados servicios de los factores), como también los pagos de transferencias.
Los datos se expresan en dólares de los Estados Unidos a precios constantes del año 2005.
import: Las importaciones de bienes y servicios representan el valor de todos
los bienes y otros servicios de mercado recibidos del resto del mundo.
Incluyen el valor de las mercaderías, fletes, seguros, transporte, viajes,
regalías, tarifas de licencia y otros servicios tales como los relativos a las
comunicaciones, la construcción, los servicios financieros, los informativos,
los empresariales, los personales y los del Gobierno.
Excluyen la remuneración de los empleados y los ingresos por inversiones
(anteriormente denominados servicios de los factores), como también los pagos de transferencias.
Los datos se expresan en dólares de los Estados Unidos a precios constantes del año 2005.
polity & polity2: La escala de democracia varía mediante la suma de los puntajes asignados
a cada país en cada una de las siguientes dimensiones:
la competitividad del proceso de selección del ejecutivo;
la apertura de ese proceso de selección;
los límites al poder del ejecutivo; y,
la competitividad de la participación política.
El régimen político vigente en un país y año determinados puede clasificarse como
democracia o autocracia según el puntaje Polity obtenido.
Se consideran democracias a los regímenes con puntajes entre +6 y +10;
autocracias, a los que tienen valores entre -6 y -10;
anocracias o regímenes híbridos –formas intermedias, mixtas o incoherentes-, a los que califican entre +5 y -5. */
******* Conociendo la informacion
describe
summarize
describe
summarize
******* Line graphs (lineas)
line unemp unempf unempm year if country=="United States"
summarize unemp unempf unempm
replace unemp=. if unemp==0
replace unempf=. if unempf==0
replace unempm=. if unempm==0
summarize unemp unempf unempm
line unemp unempf unempm year if country=="United States"
twoway line unemp unempf unempm year if country=="United States", ///
title("Tasa de desempleo en los Estados Unidos, 1980-2012") ///
legend(label(1 "Total") label(2 "Mujeres") label(3 "Varones")) ///
lpattern(solid dash dot) ///
ytitle("Porcentaje")
twoway connected unemp unempf unempm year if country=="United States", ///
title("Tasa de desempleo en los Estados Unidos, 1980-2012") ///
legend(label(1 "Total") label(2 "Mujeres") label(3 "Varones")) ///
msymbol(circle diamond square) ///
ytitle("Porcentaje")
twoway connected unemp year if country=="United States" | country=="United Kingdom" | ///
country=="Australia" | country=="Qatar", by(country, title("Desempleo")) ///
msymbol(circle_hollow)
twoway (connected unemp year if country=="United States", msymbol(diamond_hollow)) ///
(connected unemp year if country=="United Kingdom", msymbol(triangle_hollow)) ///
(connected unemp year if country=="Australia", msymbol(square_hollow)) ///
(connected unemp year if country=="Qatar", ///
title("Desempleo") msymbol(circle_hollow) ///
legend(label(1 "USA") label(2 "UK") label(3 "Australia") label(4 "Qatar")))
twoway connected gdppc year if gdppc>40000, by(country) msymbol(diamond)
bysort year: egen gdppc_mean=mean(gdppc)
bysort year: egen gdppc_median=median(gdppc)
label var gdppc_mean "Promedio PBI-PC"
label var gdppc_median "Mediana PBI-PC"
twoway connected gdppc gdppc_mean year if country=="United States" | ///
country=="United Kingdom" | country=="Australia" | country=="Qatar", ///
by(country, title("PBI pc (PPA, 2005=100)")) ///
legend(label(1 "PBI-PC") label(2 "Promedio PBI-PC")) msymbol(circle_hollow)
help twoway line
help twoway connected
******* Marcadores de graficos
palette symbolpalette
palette linepalette
palette color green
help palette
******* Grafico de barras
graph hbar (mean) gdppc /*La media es el default*/
graph hbar (mean) gdppc, over(country, sort(1) descending)
graph hbar (mean) gdppc, over(country, sort(1) descending label(labsize(*0.5)))
graph hbar (mean) gdppc (median) gdppc if gdppc>40000, ///
over(country, sort(1) descending label(labsize(*1))) ///
legend(label(1 "PBI-pc (promedio)") label(2 "PBI-pc (mediana)"))
help graph bar
*** Diagrama Box plots (gráfico de caja): busca resaltar aspectos de la distribución de la variable
* Recodificamos la variable polity2
recode polity2 (-10/-6=1 "Autocracia") (-5/6=2 "Anocracia") (7/10=3 "Democracia") ///
(else=.), gen(regime) label(polity_rec)
tab country regime /* Cross tabulations */
graph box gdppc
graph box gdppc if gdppc>40000
graph box gdppc, over(regime) yline(4517.94) marker(1,mlabel(country))
help graph box
*** Histogramas: es la representación gráfica en forma de barras,
*que simboliza la distribución de un conjunto de datos
hist gdppc, frequency /*frequencia*/
hist gdppc if country=="United States" | country=="United Kingdom", bin(5) by(country) frequency
twoway hist gdppc if country=="United States", bin(5) frequency || ///
hist gdppc if country=="United Kingdom", bin(5) frequency ///
fcolor(none) lcolor(black) legend(label(1 "USA") label(2 "UK"))
help hist
*** Scatterplots (Diagrama de dispersión):
***muestra la conexión entre el conjunto de datos que analizamos
scatter import export
twoway scatter import export || scatter import export if export>1000000, mlabel(country) legend(off)
twoway (scatter import export, ytitle("Importaciones") xtitle("Exportaciones")) ///
(scatter import export if export>1000000, mlabel(country) legend(off)) ///
(lfit import export, note("Valores constantes, 2005, millones de US$"))
scatter import export
twoway scatter import export || scatter import export if export>1000000, mlabel(country) legend(off)
twoway (scatter import export, ytitle("Importaciones") xtitle("Exportaciones")) ///
(scatter import export if export>1000000, mlabel(country) legend(off)) ///
(lfit import export, note("Valores constantes, 2005, millones de US$"))
help twoway scatter
*** Scatterplot matrix (Matriz de dispersión)
graph matrix gdppc unemp unempf unempm export import trade polity2, half maxis(ylabel(none) xlabel(none))
help graph matrix
Comentarios
Publicar un comentario