#57 Medición del Índice de Pobreza Multidimensional con la ENAHO en Stata

 

Estimad@s, en este video comparto la Medición del Índice de Pobreza Multidimensional (IPM) con la Encuesta Nacional de Hogares (ENAHO) del 2011 en Stata.
********************************************************************************

***POBREZA MULTIDIMENSIONAL

cd "D:\MULTIDIMENSIONAL"
**EDUCACION
*ABRIR MODULO 300 DE EDUCACION
use enaho01a-2011-300.dta, clear

*Escolaridad del jefe de hogar
*p301a: ultimo ahno aprobado
gen     escol_jefe=0 
replace escol_jefe=1 if p203==1 & p301a<=4

*Matricula escolar: 7-18
*p306: esta matriculado?
*p301a: ultimo ahno aprobado
gen       matri_esc=0
replace matri_esc=1 if (p208a>6 & p208a<=18) & p306==2 & p301a<=5

collapse (sum) escol_jefe matri_esc  , by(conglome vivienda hogar factor07)

*del anterior-matricula escolar, calificar cada hogar con 0 y 1 solamente
replace matri_esc=1 if matri_esc>=1
save    edu_mpi_2011.dta, replace


**SALUD
**ABRIR MODULO 400 DE SALUD
use Enaho01A-2011-400.dta, clear

*ASISTENCIA A CENTRO DE SALUD
*p4021-p4024: en las ultimas semanas presento malestar, enfermedad, recaida o accidente 
gen     malestar= p4021 + p4022 + p4023 + p4024
**se recodifica los missing con cero
recode  malestar (mis=0)
**se recodifica la variable para que tome valor 0 o 1
replace malestar=1 if malestar>=1

*RAZONES POR LAS QUE NO ACUDIO AL CENTRO DE SALUD
*p4091 (no tuvo dinero), p4092 (se encuentra lejos) & p4097 (no tiene seguro)
recode  p4091 p4092 p4097(mis=0)
gen       razones= p4091 + p4092 + p4097
replace razones=1 if razones>=1
gen       salud_asist=0
replace salud_asist=1 if malestar==1 & razones==1

*DE INDIVIDUOS A HOGARES
collapse (sum) salud_asist , by(conglome vivienda hogar factor07)
*del anterior-asistio a centro de salud, calificar cada hogar con 0 y 1 solamente
replace salud_asist=1 if salud_asist>=1
save sal_mpi_2011.dta, replace


**VIVIENDA
**ABRIR MODULO 100 VIVIENDA
use enaho01-2011-100.dta, clear
*limpiar los registros incompletos
tab     result
drop if result>=3
*se borro los registros rechazo ausentes desocupada vivienda otro

*PISO DE LA VIVIENDA
recode  p103 (mis=7)
gen     pisos=0
replace pisos=1 if p103>=6

*AGUA
gen     agua=0
replace agua=1 if p110>=4

*SERVICIO HIGIENICO
gen     desague=0
replace desague=1 if p111>1

*ALUMBRADO
gen     electricidad=0
replace electricidad=1 if p1121!=1

*COMBUSTIBLE USADO
gen     comb_coc=0
replace comb_coc=1 if p113a>=5
save    viv_mpi_2011.dta, replace

***Unimos las bases vivienda, salud y educacion
use sumaria-2011.dta, clear
merge 1:1  conglome vivienda hogar using viv_mpi_2011.dta, nogenerate
merge 1:1  conglome vivienda hogar using sal_mpi_2011.dta, nogenerate
merge 1:1  conglome vivienda hogar using edu_mpi_2011.dta, nogenerate

*se renombro año, por los caracteres
rename a*o anio

*generamos un campo "identh" para unir la base de pobreza calorica
*para ver como se genera la variable pobreza calorica ver el video 
*"Medición del Déficit Calórico con la Encuesta Nacional de Hogares (ENAHO) del 2011"
*https://youtu.be/5x5X-4Nea5o
gen str13 identh= anio+ conglome+ vivienda+ hogar

merge 1:1 identh using Pobrezacalorica2011.dta, nogenerate

*Base de datos por Hogares
*llevar hogares a personas
gen facpobmie=factor07*mieperho

**CALCULO MPI
gen pond_comb_coc     =comb_coc/15
gen pond_electricidad =electricidad/15
gen pond_desague      =desague/15
gen pond_agua         =agua/15
gen pond_pisos        =pisos/15
gen pond_caloria      =pobreC/6
gen pond_matri_esc    =matri_esc/6
gen pond_escol_jefe    =escol_jefe/6
gen pond_salud_asist  =salud_asist/6
gen MPI = pond_comb_coc  + pond_electricidad + pond_desague + pond_agua ///
               + pond_pisos          + pond_caloria   + pond_salud_asist    ///
       + pond_matri_esc   + pond_escol_jefe 

gen              pobreza_multi=0
replace        pobreza_multi=1 if MPI>0.33
label define pobreza_multi 1 "pobre" 0 "no_pobre"
label val      pobreza_multi pobreza_multi
label var      pobreza_multi "Pobreza Multidimensional"

*VARIABLE DEPARTAMENTO
destring ubigeo, generate(dpto)
replace dpto=dpto/10000
replace dpto=round(dpto)
label variable dpto "Departamento"
label define dpto 1 "Amazonas"
label define dpto 2 "Ancash", add
label define dpto 3 "Apurimac", add
label define dpto 4 "Arequipa", add
label define dpto 5 "Ayacucho", add
label define dpto 6 "Cajamarca", add
label define dpto 7 "Callao", add
label define dpto 8 "Cusco", add
label define dpto 9 "Huancavelica", add
label define dpto 10 "Huanuco", add
label define dpto 11 "Ica", add
label define dpto 12 "Junin", add
label define dpto 13 "La_Libertad", add
label define dpto 14 "Lambayeque", add
label define dpto 15 "Lima", add
label define dpto 16 "Loreto", add
label define dpto 17 "Madre_de_Dios", add
label define dpto 18 "Moquegua", add
label define dpto 19 "Pasco", add
label define dpto 20 "Piura", add
label define dpto 21 "Puno", add
label define dpto 22 "San_Martin", add
label define dpto 23 "Tacna", add
label define dpto 24 "Tumbes", add
label define dpto 25 "Ucayali", add
label values dpto dpto
tab pobreza_multi [iw=facpobmie]
tab dpto pobreza_multi [iw=facpobmie]
tab dpto pobreza_multi [iw=facpobmie], nofreq row
*usando el comando svyset para obtener el error estandar y el intervalo de confianza
svyset [pweight=facpobmie], psu(conglome) strata(estrato)
svy:mean pobreza_multi
 
svy:mean pobreza_multi, over(dpto)