#53 MINEDU-ESCALE: Tasa de conclusión primaria, edades 12-13 (% del total) usando la ENAHO en STATA


Estimad@s, en este video les muestro como estimar la Tasa de conclusión, primaria, grupo de edades 12-13 (% del total) usando la Encuesta Nacional de Hogares (ENAHO) del 2019 en STATA. Gracias a Gustavo Espinoza Peralta por compartir el do-file.
Fuentes:
MINEDU-ESCALE: http://escale.minedu.gob.pe/
INEI-MICRODATOS: http://iinei.inei.gob.pe/microdatos/ Janet Porras

****************************
*Tasa de Conclusión Primaria, 12 a 13 años (% del total)
gen conclup1213=0 if edad_31Marzo>=12 & edad_31Marzo<=13
replace conclup1213=1 if (edad_31Marzo>=12 & edad_31Marzo<=13) & (p301a>=4 & p301a<=11)
label def con_l 0 "Incompleta" 1 "Completa"
label val conclup1213 con_l tab conclup1213 [aweight=factora07]
tab p207 conclup1213 [aweight=factora07], nofreq row
tab area conclup1213 [aweight=factora07], nofreq row
tab p207 conclup1213 if area==1 [aweight=factora07], nofreq row
tab p207 conclup1213 if area==2 [aweight=factora07], nofreq row tab lengua conclup1213 [aweight=factora07], nofreq row
tab pobreza conclup1213 [aweight=factora07], nofreq row
tab dpto conclup1213 [aweight=factora07], nofreq row

*************************

*Tasa de conclusión
clear all

cd "D:\CONCLUSION"

*Unir las bases del módulo salud, educación y sumaria
use "enaho01a-2019-400.dta",clear
merge 1:1 conglome vivienda hogar codperso using  "enaho01a-2019-300.dta"
keep if _merge==3
drop _m
merge m:1 conglome vivienda hogar using "sumaria-2019.dta", nogenerate

*Estimar edad en años cumplidos al 31 de Marzo
rename   a*o year
destring year, replace
gen      edad_31Marzo=year-p400a3     if p400a2<4
replace  edad_31Marzo=(year-p400a3-1) if p400a2>3 & p400a2<=12
replace  edad_31Marzo=0 if edad_31Marzo<0

*Variables geográficas (departamento, urbano/rural)
*Departamento (distinguir Lima Metropolitana de Lima Provincias)
destring ubigeo, generate(dpto)
replace dpto=dpto/10000
replace dpto=round(dpto)
replace dpto=26 if (dominio==8) //Lima Metropolitana
replace dpto=27 if (dpto==15 & dominio!=8) //Lima Provincias

label define dpto_num 1  "Amazonas"
label define dpto_num 2  "Ancash",       add
label define dpto_num 3  "Apurimac",     add
label define dpto_num 4  "Arequipa",     add
label define dpto_num 5  "Ayacucho",     add
label define dpto_num 6  "Cajamarca",    add
label define dpto_num 7  "Callao",       add
label define dpto_num 8  "Cusco",        add
label define dpto_num 9  "Huancavelica", add
label define dpto_num 10 "Huanuco",      add
label define dpto_num 11 "Ica",          add
label define dpto_num 12 "Junin",        add
label define dpto_num 13 "La_Libertad",  add
label define dpto_num 14 "Lambayeque",   add
*label define dpto_num 15 "Lima",         add
label define dpto_num 16 "Loreto",       add
label define dpto_num 17 "Madre_de_Dios",add
label define dpto_num 18 "Moquegua",     add
label define dpto_num 19 "Pasco",        add
label define dpto_num 20 "Piura",        add
label define dpto_num 21 "Puno",         add
label define dpto_num 22 "San_Martin",   add
label define dpto_num 23 "Tacna",        add
label define dpto_num 24 "Tumbes",       add
label define dpto_num 25 "Ucayali",      add
label define dpto_num 26 "Lima_Metropolitana",   add
label define dpto_num 27 "Lima_Provincias",      add
label values dpto dpto_num

*Area
recode estrato (1/5=1 "Urbana")(6/8=2 "Rural"), gen(area)
lab var area "Area de Residencia"

*Etiquetar la variable pobreza monetaria
*Usar variable "pobreza" de sumaria
label define pobre_3 1 "pobre_extremo" 2 "pobre_no_extremo" 3 "no_pobre"
label value  pobreza pobre_3

*Crear la variable lengua materna
*Lengua indígena: quechua, aymara, otra lengua nativa
*Lengua Castellano
recode p300a (4=1 "Castellano")(1/3=2 "Indigena")(5/9=.), gen(lengua)

Comentarios

  1. Muy buenos tus vídeos sobre Stata y el manejo de ellas en las diferentes bases de datos.

    ResponderEliminar
  2. Hola Janet, gracias por tu aporte al análisis de base de datos. Quería hacerte una consulta, estoy tratando de calcular la tasa neta de asistencia de primaria para el 2019, he tratado de hacerlo de manera similar a lo de conclusión, sin embargo no obtengo los resultados que nos brinda el Minedu. A continuación te paso el código, para que puedas por favor ver en que me estoy equivocando

    *Unir bases de datos del módulo salud, educación y sumaria
    use "enaho01a-2019-400", clear
    merge 1:1 conglome vivienda hogar codperso using "enaho01a-2019-300.dta"
    keep if _merge==3
    drop _m
    merge m:1 conglome vivienda hogar using "sumaria-2019.dta"

    ***Estimar edad en años cumplidos al 31 de marzo
    destring aÑo, replace
    gen edad_31Marzo=aÑo-p400a3 if p400a2<4
    replace edad_31Marzo= (aÑo-p400a3-1) if p400a2>3 & p400a2<=12
    replace edad_31Marzo=0 if edad_31Marzo<0

    *Area
    recode estrato (1/5=1 "Urbana")(6/8=2 "Rural"), gen(area)
    lab var area "Area de Residencia"

    *Etiquetar la variable pobreza monetaria
    *Usar variable "pobreza" de sumaria
    label define pobre_3 1 "pobre_extremo" 2 "pobre_no_extremo" 3 "no_pobre"
    label val pobreza pobre_3

    *Crear la variable lengua materna
    **Lengua indígena: quechua, aymara, otra lengua nativa
    *Lengua Castellano
    recode p300a (4=1 "Castellano")(1/3=2 "Indigena")(5/9=.), gen(lengua)

    ***
    *Tasa de asistencia primaria, 6 a 11 años (% del total)

    gen asistprim=0 if edad_31Marzo>=6 & edad_31Marzo<=11 & p400a2>=4
    replace asistprim=1 if (edad_31Marzo>=6 & edad_31Marzo<=11 & p400a2>=4)&(p307==1 & p308a==2)
    label def asis_l 0 "no selecc" 1 "selec"
    label val asistprim asis_l
    tab asistprim

    muchas gracias de antemano

    ResponderEliminar

Publicar un comentario