Hola a tod@s, adjunto la sintaxis para estimar la prevalencia de enfermedad diarreica aguda (EDA) usando la ENDES del 2019 en Stata.
Janet Porras
**********
*INCIDENCIA DE ENFERMEDAD DIARREICA AGUDA (EDA)
*Especificamos nuestra carpeta de trabajo
cd "E:\ENDES"
*Bajar los siguientes modulos de la ENDES 2019 y descomprimir las carpetas:
*Modulo66\rec0111
*Modulo66\rec91
*Modulo67\rec21
*Modulo70\rec42
*Modulo70\rec43
import dbase Modulo66\REC0111.dbf, clear
label define V015 1 "Completa" 2 "Ausente" 3 "Aplazada" 4 "Rechazada" ///
5 "Respondida parcialmente" 6 "Incapacitada" 7 "Otra"
label values V015 V015
label var V015 "Resultado de entrevista individual"
label var HHID "Identificacion Cuestionario del Hogar"
label var CASEID "Identificacion Cuestionario Individual"
label var V012 "Edad actual -Age in single years"
label var V013 "Edad actual por grupos de 5 años"
label define V013 0 "De 12 a 14 años de edad" 1"De 15 a 19 años de edad" ///
2"De 20 a 24 años de edad" 3"De 25 a 29 años de edad" 4"De 30 a 34 años de edad" ///
5"De 35 a 39 años de edad" 6"De 40 a 44 años de edad" 7"De 45 a 49 años de edad"
label values V013 V013
recode V013 (0=0) (1=1) (2 3=2) (4 5=3) (6 7=4), gen(gedad)
label define gedad 0 "De 12 a 14 años de edad" 1"De 15 a 19 años de edad" ///
2"De 20 a 29 años de edad" 3"De 30 a 39 años de edad" 4"De 40 a 49 años de edad"
label values gedad gedad
label var V001 "Conglomerado"
label var V002 "Número de vivienda"
label var V003 "Número de línea de entrevistada"
label var V005 "Factor de ponderación mujer"
label var V008 "Fecha de la entrevista, Codificación centenaria de meses (CMC)"
label var V011 "Fecha de nacimiento, Codificación centenaria de meses (CMC)"
label var V021 "Unidad de muestreo primario - conglomerado"
label var V024 "Región"
label var V025 "Tipo de lugar de residencia"
label define V025 1 "Urbano" 2 "Rural"
label values V025 V025
label var V042 "Selección de hogar para hemoglobina"
label var V043 "Selección para módulo de estatus de mujeres"
label var V044 "Selección para módulo de violencia domestica"
label var V101 "Región"
label var V102 "Tipo de lugar de residencia"
label var V106 "Nivel educativo más alto"
label define V106 0 "Sin educación" 1 "Primaria" 2 "Secundaria" 3 "Superior"
label values V106 V106
label var V129 "Material predominante del techo de la vivienda"
label var V133 "Educación en años simples"
label var V135 "Residente habitual o visitante"
label var V149 "Logro educativo"
label define V149 0 "Sin educación" 1 "Primaria incompleta" 2 "Primaria completa" ///
3 "Secundaria incompleta" 4 "Secundaria completa" 5 "Superior"
label values V149 V149
label var V190 "Índice de riqueza"
label define V190 1 "Quintil_inferior" 2 "Segundo_quintil" 3 "Quintil_intermedio" ///
4 "Cuarto_quintil" 5 "Quintil_superior"
label values V190 V190
label var AWFACTT "Factor todas las mujeres"
label var AWFACTU "Factor todas las mujeres - urbano/rural"
label var AWFACTR "Factor todas las mujeres - regional"
label var AWFACTE "Factor todas las mujeres - educación"
label var AWFACTW "Factor todas las mujeres - índice de riqueza"
foreach v of var * {
rename `v' `=lower("`v'")'
}
save REC0111.dta, replace
import dbase Modulo66\REC91.dbf, clear
label define SREGION 1 "Lima_Metropolitana" 2 "Resto_Costa" 3 "Sierra" 4 "Selva"
label values SREGION SREGION
label var SREGION "Region Natural"
recode SREGION (1 2=1) (3=2) (4=3), gen(region_natural)
label define region_natural 1 "Costa" 2 "Sierra" 3 "Selva"
label values region_natural region_natural
label var CASEID "Identificacion Cuestionario Individual"
label var S108N "Nivel educativo aprobado"
label var S111 "Actualmente asiste a la escuela, colegio, instituto o universidad"
label var S112 "Razón por que dejo de asistir a la escuela"
label var S119 "Idioma o lengua materna que aprendió hablar en su niñez"
recode S119 (10=1) (1/9=2) (11 12=3), gen(lmaterna)
label define lmaterna 1 "Castellano" 2 "Lengua nativa 4/" 3 "Extranjera"
label values lmaterna lmaterna
label var lmaterna "Lengua Materna"
label var S119NA "Idioma materna su madre"
label var S119NB "Lengua materna su padre"
label var S119D "Por sus antepasados y costumbres, Ud. Se considera"
label define S119D 1 "Quechua" 2 "Aimara" 3 "Nativo o indigena de la Amazonía" ///
4 "Parte de otro pueblo indigena u originario" 5"Negro/ Moreno/ Zambo/ Mulato/Pueblo Afroperuano o afrodescendiente" ///
6 "Blanco" 7 "Mestizo" 8 "Otro" 98 "No sabe"
label values S119D S119D
recode S119D (1 2 3 4=1) (5=2) (6=3) (7=4) (8 98=5), gen(etnia)
label define etnia 1 "Origen nativo 2/" 2"Negro, moreno, zambo 3/" 3 "Blanco" 4 "Mestizo" 5 "Otro/ No sabe"
label values etnia etnia
label var S229B1 "Afiliada a seguro de salud (seguro integral)"
foreach v of var * {
rename `v' `=lower("`v'")'
}
save REC91.dta, replace
import dbase Modulo67\REC21.dbf, clear
label var CASEID "Identificacion Cuestionario Individual"
label var BIDX "Número de orden de nacimiento"
label var B3 "Fecha de nacimiento, Codificación centenaria de meses (CMC)"
label var B4 "Sexo del niño"
label define sexo 1 "Hombre" 2 "Mujer"
label values B4 sexo
label var B5 "Nihno esta vivo"
label var B7 "Edad a la muerte (meses-imputado)"
label var B9 "Con quien vive el niño"
label define B9 0 "Entrevistada" 1 "Padre" 2 "Otro pariente" 3 "Alguien más" 4 "Vive en otro lugar"
label values B9 B9
label var QD333_1 "Alg. dificultad o limitacion ver"
label var QD333_2 "Alg. dificultad o limitacion oir, aún usando audífonos"
label var QD333_3 "Alg. dificultad o limitacion hablar o comunicarse"
label var QD333_4 "Alg. dificultad o limitacion moverse o caminar para usar brazos y/o piernas"
label var QD333_5 "Alg. dificultad o limitacion entender o aprender"
label var QD333_6 "Alg. dificultad o limitacion relacionarse con los demás"
rename BIDX MIDX
sort CASEID MIDX
foreach v of var * {
rename `v' `=lower("`v'")'
}
save REC21.dta, replace
import dbase Modulo70\REC42.dbf, clear
label define nosi 0 "No" 1 "Sí" 8 "No sabe"
label var CASEID "Identificación Cuestionario Individual"
label var V404 "Actualmente amamantando"
label var V409 "Ayer durante el dìa o la noche dio agua sola al niño"
label var V409A "Ayer durante el dìa o la noche dio agua azucarada"
label var V410 "Ayer durante el dìa o la noche dio jugo de fruta al niño"
label var V410A "Ayer durante el dìa o la noche dio al niño té o café"
label var V411 "Ayer durante el dìa o la noche dio al niño leche materna refrigerada/conservada"
label var V411A "Ayer durante el dìa o la noche dio al niño leche en polvo"
label var V412 "Ayer durante el dìa o la noche dio al niño otra leche fresca, evaporada o en polvo"
label var V412A "Ayer durante el dìa o la noche dio al niño cereales para bebes"
label var V412B "Ayer durante el dìa o la noche dio al niño otros cereales"
label var V413 "Ayer durante el dìa o la noche dio al niño otro líquido como bebidas gaseosas, caldo"
label var V413A "Ayer durante el dìa o la noche dio líquido CS infantil"
label var V413B "Ayer durante el dìa o la noche dio líquido CS infantil"
label var V413C "Ayer durante el dìa o la noche dio líquido CS infantil"
label var V413D "Ayer durante el dìa o la noche dio líquido CS infantil"
label var V414A "Ayer durante el dìa o la noche dio al niño naranjas mandarina, lima, maracuyá, toronja"
label var V414B "Ayer durante el dìa o la noche dio al niño papillas de programas sociales"
label var V414C "Ayer durante el dìa o la noche dio al niño frutas secas"
label var V414D "Ayer durante el dìa o la noche dio alimentos CS para niños"
label var V414E "Ayer durante el dìa o la noche dio al niño harina, pan u cualquier comida hecha de cereales"
label var V414F "Ayer durante el dìa o la noche dio al niño comida hecha de tubérculos o raíces"
label var V414G "Ayer durante el dìa o la noche dio al niño huevos"
label var V414H "Ayer durante el dìa o la noche dio al niño carne de res, pollo, pescado, otras carnes, hígado, mondongo, otras vísceras"
label var V414I "Ayer durante el dìa o la noche dio al niño camote, zanahorias, zapallo"
label var V414J "Ayer durante el dìa o la noche dio al niño cualquier vegetal de hoja verde oscuro"
label var V414K "Ayer durante el dìa o la noche dio al niño mango, papaya aguaje y otras frutas de vitamina A"
label var V414L "Ayer durante el dìa o la noche dio al niño otras frutas"
label var V414M "Ayer durante el dìa o la noche dio hígado, corazón y otros órganos al niño"
label var V414N "Ayer durante el dìa o la noche dio al niño pescado o mariscos"
label var V414O "Ayer durante el dìa o la noche dio al niño habas, frijol, lenteja, soya, pallares, garbanzo, arvejas"
label var V414P "Ayer durante el dìa o la noche dio al niño queso, yogurt u otros productos lácteos"
label var V414Q "Ayer durante el dìa o la noche dio al niño comida hecha con aceite, grasas, mantequilla, productos hechos de ellos"
label var V414R "Ayer durante el dìa o la noche dio al niño alimento azucarado como chocolates, caramelos u otros"
label var V414S "Ayer durante el dìa o la noche dio al niño otro alimento sólido-semisólido"
label var V414T "Ayer durante el dìa o la noche dio alimentos CS para niños"
label var V414U "Ayer durante el dìa o la noche dio alimentos CS para niños"
label values V409-V414U nosi
label var V455 "Resultado de medir (hemoglobina)"
label var V456 "Nivel de hemoglobina ajustado por altitud (g/dl - 1 decimal)"
label var V457 "Nivel de anemia"
label define V457 1 "Grave" 2 "Moderar" 3 "Templado" 4 "No anémico"
label values V457 V457
label var V463A "Fuma cigarrillos"
label val V463A nosi
label var V463B "Pipa de humo"
label var V463C "Mascando tabaco"
label var V463D "Utiliza tabaco"
label var V463Z "No fuma"
label var V474 "Escuchó sobre la Tuberculosis o TBC"
label var V481 "Cobertura de seguro de salud"
foreach v of var * {
rename `v' `=lower("`v'")'
}
save REC42.dta, replace
import dbase Modulo70\REC43.dbf, clear
/* contienen información sobre Inmunización y morbilidad: Vacunas que
recibió el bebé, tratamiento recibido para la tos, fiebre, diarrea,
establecimiento de salud dónde recibió tratamiento, etc */
label var CASEID "Identificación Cuestionario Individual"
label var HIDX "Nro. orden de historia de nacimiento"
label var H2 "Recibió vacuna BCG"
label var H3 "Recibió vacuna DPT 1ra. dosis"
label var H4 "Recibió vacuna POLIO 1ra. dosis"
label var H11 "En los últimos 14 dìas, ha tenido diarrea la niña(o)"
label define nosi 0 "No" 1 "Sí, las últimas 24 horas" 2 "Sí, las últimas dos semanas" 8 "No sabe"
label values H11 nosi
label var H31 "Ha tenido tos en las últimas dos semanas"
label values H31 nosi
label var H31B "Cuando estuvo enfermo con tos, respiraba más rápido con respiraciones cortas y rápidas"
label var H31C "La respiración rápida o difícil era por un problema en el pecho o porque tenía la nariz tupida"
rename HIDX MIDX
foreach v of var * {
rename `v' `=lower("`v'")'
}
save REC43.dta, replace
********************************************************************************
use rec0111, clear
merge 1:1 caseid using "rec91", nogen
merge 1:1 caseid using "rec42", nogen
save rec0111_rec91_rec42.dta, replace
use rec21, clear
merge 1:1 caseid midx using "rec43", nogen
save rec21_rec43.dta, replace
use rec0111_rec91_rec42.dta, clear
merge 1:m caseid using "rec21_rec43", nogen
*Factor de expansion
gen wt=v005/1000000
*Generamos la variable EDADM
gen edadm=v008-b3
recode edadm (0/5=1 "Menos de 6 meses")(6/11=2 "6-11")(12/23=3 "12-23") ///
(24/35=4 "24-35")(36/47=5 "36-47")(48/59=6 "48-59")(nonm=.), gen(gedadm)
recode h11(0 8=1 "No")(2=2 "Si") if b5==1 & edadm<60 & v012>14 , gen(eda)
tab eda [iweight=wt]
tab gedadm eda [iweight=wt], nofreq row
tab b4 eda [iweight=wt], nofreq row
tab v463a eda [iweight=wt], nofreq row
tab v190 eda [iweight=wt], nofreq row
tab v025 eda [iweight=wt], nofreq row
tab region_natural eda [iweight=wt], nofreq row
tab etnia eda [iweight=wt], nofreq row
tab lmaterna eda [iweight=wt], nofreq row
Comentarios
Publicar un comentario