Hola a tod@s, les comparto la sintaxis para estimar el porcentaje de vacunados entre menores de 12 meses de edad por tipo de vacuna usando la ENDES del 2019 en Stata.
Janet Porras
***
*Especificamos nuestra carpeta de trabajo
cd "E:\ENDES"
*Bajar y descomprimir los modulos 66, 67 y 70
import dbase Modulo66\REC0111.dbf, clear
label define V015 1 "Completa" 2 "Ausente" 3 "Aplazada" 4 "Rechazada" ///
5 "Respondida parcialmente" 6 "Incapacitada" 7 "Otra"
label values V015 V015
label var V015 "Resultado de entrevista individual"
label var HHID "Identificacion Cuestionario del Hogar"
label var CASEID "Identificacion Cuestionario Individual"
label var V012 "Edad actual -Age in single years"
label var V013 "Edad actual por grupos de 5 años"
label define V013 0 "12 a 14 años" 1"15 a 19 años" 2"20 a 24 años" 3"25 a 29 años" ///
4"30 a 34 años" 5"35 a 39 años" 6"40 a 44 años" 7"45 a 49 años"
label values V013 V013
recode V013 (0=0) (1=1) (2 3=2) (4 5=3) (6 7=4), gen(gedad)
label define gedad 0 "12 a 14 años" 1"15 a 19 años" ///
2"20 a 29 años" 3"30 a 39 años" 4"40 a 49 años"
label values gedad gedad
label var V001 "Conglomerado"
label var V002 "Número de vivienda"
label var V003 "Número de línea de entrevistada"
label var V005 "Factor de ponderación mujer"
label var V008 "Fecha de la entrevista, Codificación centenaria de meses (CMC)"
label var V011 "Fecha de nacimiento, Codificación centenaria de meses (CMC)"
label var V021 "Unidad de muestreo primario - conglomerado"
label var V024 "Región"
label var V025 "Tipo de lugar de residencia"
label define V025 1 "Urbano" 2 "Rural"
label values V025 V025
label var V042 "Selección de hogar para hemoglobina"
label var V043 "Selección para módulo de estatus de mujeres"
label var V044 "Selección para módulo de violencia domestica"
label var V101 "Región"
label var V102 "Tipo de lugar de residencia"
label var V106 "Nivel educativo más alto"
label define V106 0 "Sin educación" 1 "Primaria" 2 "Secundaria" 3 "Superior"
label values V106 V106
label var V129 "Material predominante del techo de la vivienda"
label var V133 "Educación en años simples"
label var V135 "Residente habitual o visitante"
label var V149 "Logro educativo"
label define V149 0 "Sin educación" 1 "Primaria incompleta" 2 "Primaria completa" ///
3 "Secundaria incompleta" 4 "Secundaria completa" 5 "Superior"
label values V149 V149
label var V155 "Alfabetización"
label define V155 0 "No puede leer" 1 "Puede leer sólo parte de la frase" ///
2 "Puede leer la frase" 3 "No hay tarjeta en el idioma requerido" ///
4 "Ciega/problemas visuales"
label values V155 V155
label var QD333_1 "Alguna dificultad/limitación permanente para ver, aún usando anteojos"
label var QD333_2 "Alguna dificultad/limitación permanente para oir, aún usando audífonos"
label var QD333_3 "Alguna dificultad/limitación permanente para hablar o comunicarse, aún usando la lengua de señas u otro"
label var QD333_4 "Alguna dificultad/limitación permanente para moverse o caminar para usar brazos y/o piernas"
label var QD333_5 "Alguna dificultad o limitación permanente para entender o aprender (concentrarse y recordarse)"
label var QD333_6 "Alguna dificultad o limitación permanente para relacionarse con los demás, por sus pensamientos, sentimientos, emociones o conductas"
label var V190 "Índice de riqueza"
label define V190 1 "Quintil_inferior" 2 "Segundo_quintil" 3 "Quintil_intermedio" ///
4 "Cuarto_quintil" 5 "Quintil_superior"
label values V190 V190
label var AWFACTT "Factor todas las mujeres"
label var AWFACTU "Factor todas las mujeres - urbano/rural"
label var AWFACTR "Factor todas las mujeres - regional"
label var AWFACTE "Factor todas las mujeres - educación"
label var AWFACTW "Factor todas las mujeres - índice de riqueza"
foreach v of var * {
rename `v' `=lower("`v'")'
}
save REC0111.dta, replace
import dbase Modulo67\REC21.dbf, clear
label var CASEID "Identificacion Cuestionario Individual"
label var BIDX "Número de orden de nacimiento"
label var BORD "Número de orden en la historia de nacimiento"
label var B3 "Fecha de nacimiento, Codificación centenaria de meses (CMC)"
label var B4 "Sexo del niño"
label define B4 1 "Hombre" 2 "Mujer"
label values B4 B4
label var B5 "Nihno esta vivo"
label var B7 "Edad a la muerte (meses-imputado)"
label var B9 "Con quien vive el niño"
label define B9 0 "Entrevistada" 1 "Padre" 2 "Otro pariente" 3 "Alguien más" 4 "Vive en otro lugar"
label values B9 B9
label var QD333_1 "Alg. dificultad o limitacion ver"
label var QD333_2 "Alg. dificultad o limitacion oir, aún usando audífonos"
label var QD333_3 "Alg. dificultad o limitacion hablar o comunicarse"
label var QD333_4 "Alg. dificultad o limitacion moverse o caminar para usar brazos y/o piernas"
label var QD333_5 "Alg. dificultad o limitacion entender o aprender"
label var QD333_6 "Alg. dificultad o limitacion relacionarse con los demás"
rename BIDX MIDX
sort CASEID MIDX
foreach v of var * {
rename `v' `=lower("`v'")'
}
save REC21.dta, replace
import dbase Modulo70\REC43.dbf, clear
label define vacuna 0 "No" 1 "Vacuna fecha en la tarjeta" 2 "Reportado por la madre" ///
3 "Vacuna marcado en la tarjeta" 8 "No sabe"
label var CASEID "Identificación Cuestionario Individual"
label var HIDX "Nro. orden de historia de nacimiento"
label var H0 "Recibió vacuna POLIO 0"
label var H1 "Tiene el carné de atención integral de la niña(o)"
label var H2 "Recibió vacuna BCG"
label var H3 "Recibió vacuna DPT 1ra. dosis"
label var H4 "Recibió vacuna POLIO 1ra. dosis"
label var H5 "Recibió vacuna DPT 2da. dosis"
label var H6 "Recibió vacuna POLIO 2da. dosis"
label var H7 "Recibió vacuna DPT 3ra. dosis"
label var H8 "Recibió vacuna POLIO 3ra. dosis"
label values H0 H1 H2 H3 H4 H5 H6 H7 H8 vacuna
label var H11 "En los últimos 14 dìas, ha tenido diarrea la niña(o)"
label define nosi 0 "No" 1 "Sí, las últimas 24 horas" 2 "Sí, las últimas dos semanas" 8 "No sabe"
label values H11 nosi
label var H31 "Ha tenido tos en las últimas dos semanas"
label values H31 nosi
label var H31B "Cuando estuvo enfermo con tos, respiraba más rápido con respiraciones cortas y rápidas"
label var H31C "La respiración rápida o difícil era por un problema en el pecho o porque tenía la nariz tupida"
label var H33D "Vitamina A1 día"
label var H33M "Vitamina A1 mes"
label var H33Y "Vitamina A1 año"
label var H34 "Vitamina A en los últimos 6 meses"
label var H42 "Tomando píldoras de hierro, jarabe"
label var H43 "Medicamentos para parásitos intestinales en los últimos 6 meses"
rename HIDX MIDX
foreach v of var * {
rename `v' `=lower("`v'")'
}
save REC43.dta, replace
use rec21, clear
merge 1:1 caseid midx using "rec43", nogen
save rec21_rec43.dta, replace
use rec0111.dta, clear
merge 1:m caseid using "rec21_rec43", nogen
*Factor de expansion
gen wt=v005/1000000
*Edad
gen age=v008-b3
*Fuente de información
recode h1 (1=1 "tarjeta") (else=2 "madre"), gen(source)
*Etiqueta
label define sino 1 "Si" 0 "No"
*Vacunación menores de 12 meses
*** BCG
//BCG -cualquier fuente
recode h2 (1 2 3=1) (else=0), gen(ch_bcg_either)
//BCG -reportada por la madre
gen ch_bcg_moth=ch_bcg_either
replace ch_bcg_moth=0 if source==1
//BCG -tarjeta de vacunación
gen ch_bcg_card=ch_bcg_either
replace ch_bcg_card=0 if source==2
label values ch_bcg* sino
label var ch_bcg_card "BCG -tarjeta de vacunación"
label var ch_bcg_moth "BCG -reportada por la madre"
label var ch_bcg_either "BCG -cualquier fuente"
tab ch_bcg_card [iweight=wt] if v012>14 & age<12 & b5==1
tab ch_bcg_moth [iweight=wt] if v012>14 & age<12 & b5==1
tab ch_bcg_either [iweight=wt] if v012>14 & age<12 & b5==1
*Vacunas que requieren mas de una dosis
gen dosis1=age>2
gen dosis2=age>4
gen dosis3=age>6
*** Pentavalente
//DPT 1, 2, 3 -cualquier fuente
recode h3 (1 2 3=1) (else=0), gen(dpt1)
recode h5 (1 2 3=1) (else=0), gen(dpt2)
recode h7 (1 2 3=1) (else=0), gen(dpt3)
gen dptsum= dpt1+dpt2+dpt3
*Este paso se realiza para vacunas que requieren mas de una dosis para
*considerar cualquier vacio en la historia de vacunacion
gen ch_pent1_either=dptsum>=1 if dosis1==1
gen ch_pent2_either=dptsum>=2 if dosis2==1
gen ch_pent3_either=dptsum>=3 if dosis3==1
//DPT 1, 2, 3 -reportada por la madre
gen ch_pent1_moth=ch_pent1_either
replace ch_pent1_moth=0 if source==1 & dosis1==1
gen ch_pent2_moth=ch_pent2_either
replace ch_pent2_moth=0 if source==1 & dosis2==1
gen ch_pent3_moth=ch_pent3_either
replace ch_pent3_moth=0 if source==1 & dosis3==1
//DPT 1, 2, 3 -tarjeta de vacunacion
gen ch_pent1_card=ch_pent1_either
replace ch_pent1_card=0 if source==2 & dosis1==1
gen ch_pent2_card=ch_pent2_either
replace ch_pent2_card=0 if source==2 & dosis2==1
gen ch_pent3_card=ch_pent3_either
replace ch_pent3_card=0 if source==2 & dosis3==1
drop dpt1 dpt2 dpt3 dptsum
label values ch_pent* sino
label var ch_pent1_card "Pentavalente 1ra dosis vacuna -tarjeta de vacunacion"
label var ch_pent1_moth "Pentavalente 1ra dosis vacuna -reportada por la madre"
label var ch_pent1_either "Pentavalente 1ra dosis vacuna -cualquier fuente"
label var ch_pent2_card "Pentavalente 2da dosis vacuna -tarjeta de vacunacion"
label var ch_pent2_moth "Pentavalente 2da dosis vacuna -reportada por la madre"
label var ch_pent2_either "Pentavalente 2da dosis vacuna -cualquier fuente"
label var ch_pent3_card "Pentavalente 3ra dosis vacuna -tarjeta de vacunacion"
label var ch_pent3_moth "Pentavalente 3ra dosis vacuna -reportada por la madre"
label var ch_pent3_either "Pentavalente 3ra dosis vacuna -cualquier fuente"
tab ch_pent1_card [iweight=wt] if v012>14 & age<12 & b5==1
tab ch_pent1_moth [iweight=wt] if v012>14 & age<12 & b5==1
tab ch_pent1_either [iweight=wt] if v012>14 & age<12 & b5==1
tab ch_pent2_card [iweight=wt] if v012>14 & age<12 & b5==1
tab ch_pent2_moth [iweight=wt] if v012>14 & age<12 & b5==1
tab ch_pent2_either [iweight=wt] if v012>14 & age<12 & b5==1
tab ch_pent3_card [iweight=wt] if v012>14 & age<12 & b5==1
tab ch_pent3_moth [iweight=wt] if v012>14 & age<12 & b5==1
tab ch_pent3_either [iweight=wt] if v012>14 & age<12 & b5==1
*** Polio ***
//polio 1, 2, 3 cualquier fuente
recode h4 (1 2 3=1) (else=0), gen(polio1)
recode h6 (1 2 3=1) (else=0), gen(polio2)
recode h8 (1 2 3=1) (else=0), gen(polio3)
gen poliosum=polio1 + polio2 + polio3
gen ch_polio1_either=poliosum>=1 if dosis1==1
gen ch_polio2_either=poliosum>=2 if dosis2==1
gen ch_polio3_either=poliosum>=3 if dosis3==1
//polio 1, 2, 3 -reportada por la madre
gen ch_polio1_moth=ch_polio1_either
replace ch_polio1_moth=0 if source==1 & dosis1==1
gen ch_polio2_moth=ch_polio2_either
replace ch_polio2_moth=0 if source==1 & dosis2==1
gen ch_polio3_moth=ch_polio3_either
replace ch_polio3_moth=0 if source==1 & dosis3==1
//polio 1, 2, 3 -tarjeta de vacunacion
gen ch_polio1_card=ch_polio1_either
replace ch_polio1_card=0 if source==2 & dosis1==1
gen ch_polio2_card=ch_polio2_either
replace ch_polio2_card=0 if source==2 & dosis2==1
gen ch_polio3_card=ch_polio3_either
replace ch_polio3_card=0 if source==2 & dosis3==1
drop poliosum polio1 polio2 polio3
label values ch_polio* sino
label var ch_polio1_card "Polio 1ra dosis vacuna -tarjeta de vacunacion"
label var ch_polio1_moth "Polio 1ra dosis vacuna -reportada por la madre"
label var ch_polio1_either "Polio 1ra dosis vacuna -cualquier fuente"
label var ch_polio2_card "Polio 2da dosis vacuna -tarjeta de vacunacion"
label var ch_polio2_moth "Polio 2da dosis vacuna -reportada por la madre"
label var ch_polio2_either "Polio 2da dosis vacuna -cualquier fuente"
label var ch_polio3_card "Polio 3ra dosis vacuna -tarjeta de vacunacion"
label var ch_polio3_moth "Polio 3ra dosis vacuna -reportada por la madre"
label var ch_polio3_either "Polio 3ra dosis vacuna -cualquier fuente"
tab ch_polio1_card [iweight=wt] if v012>14 & age<12 & b5==1
tab ch_polio1_moth [iweight=wt] if v012>14 & age<12 & b5==1
tab ch_polio1_either [iweight=wt] if v012>14 & age<12 & b5==1
tab ch_polio2_card [iweight=wt] if v012>14 & age<12 & b5==1
tab ch_polio2_moth [iweight=wt] if v012>14 & age<12 & b5==1
tab ch_polio2_either [iweight=wt] if v012>14 & age<12 & b5==1
tab ch_polio3_card [iweight=wt] if v012>14 & age<12 & b5==1
tab ch_polio3_moth [iweight=wt] if v012>14 & age<12 & b5==1
tab ch_polio3_either [iweight=wt] if v012>14 & age<12 & b5==1
Comentarios
Publicar un comentario