Hola a tod@s, comparto la sintaxis para estimar el porcentaje de menores de 6 a 59 meses que recibieron suplemento de hierro y medicamento desparasitante por ámbito geográfico usando la Encuesta Demográfica y de Salud Familiar (ENDES)
del 2019 en STATA.
Janet Porras
*****
*Especificamos nuestra carpeta de trabajo
cd "E:\ENDES"
*Bajar y descomprimir los modulos 66, 67 y 70
import dbase Modulo66\REC0111.dbf, clear
label define V015 1 "Completa" 2 "Ausente" 3 "Aplazada" 4 "Rechazada" ///
5 "Respondida parcialmente" 6 "Incapacitada" 7 "Otra"
label values V015 V015
label var V015 "Resultado de entrevista individual"
label var HHID "Identificacion Cuestionario del Hogar"
label var CASEID "Identificacion Cuestionario Individual"
label var V012 "Edad actual -Age in single years"
label var V013 "Edad actual por grupos de 5 años"
label define V013 0 "12 a 14 años" 1"15 a 19 años" 2"20 a 24 años" 3"25 a 29 años" ///
4"30 a 34 años" 5"35 a 39 años" 6"40 a 44 años" 7"45 a 49 años"
label values V013 V013
recode V013 (0=0) (1=1) (2 3=2) (4 5=3) (6 7=4), gen(gedad)
label define gedad 0 "12 a 14 años" 1"15 a 19 años" ///
2"20 a 29 años" 3"30 a 39 años" 4"40 a 49 años"
label values gedad gedad
label var V001 "Conglomerado"
label var V002 "Número de vivienda"
label var V003 "Número de línea de entrevistada"
label var V005 "Factor de ponderación mujer"
label var V008 "Fecha de la entrevista, Codificación centenaria de meses (CMC)"
label var V011 "Fecha de nacimiento, Codificación centenaria de meses (CMC)"
label var V021 "Unidad de muestreo primario - conglomerado"
label var V022 "Estratos"
label var V024 "Región"
label var V025 "Tipo de lugar de residencia"
label define V025 1 "Urbano" 2 "Rural"
label values V025 V025
label var V042 "Selección de hogar para hemoglobina"
label var V043 "Selección para módulo de estatus de mujeres"
label var V044 "Selección para módulo de violencia domestica"
label var V101 "Región"
label var V102 "Tipo de lugar de residencia"
label var V106 "Nivel educativo más alto"
label define V106 0 "Sin educación" 1 "Primaria" 2 "Secundaria" 3 "Superior"
label values V106 V106
label var V129 "Material predominante del techo de la vivienda"
label var V133 "Educación en años simples"
label var V135 "Residente habitual o visitante"
label var V149 "Logro educativo"
label define V149 0 "Sin educación" 1 "Primaria incompleta" 2 "Primaria completa" ///
3 "Secundaria incompleta" 4 "Secundaria completa" 5 "Superior"
label values V149 V149
label var V155 "Alfabetización"
label define V155 0 "No puede leer" 1 "Puede leer sólo parte de la frase" ///
2 "Puede leer la frase" 3 "No hay tarjeta en el idioma requerido" ///
4 "Ciega/problemas visuales"
label values V155 V155
label var QD333_1 "Alguna dificultad/limitación permanente para ver, aún usando anteojos"
label var QD333_2 "Alguna dificultad/limitación permanente para oir, aún usando audífonos"
label var QD333_3 "Alguna dificultad/limitación permanente para hablar o comunicarse, aún usando la lengua de señas u otro"
label var QD333_4 "Alguna dificultad/limitación permanente para moverse o caminar para usar brazos y/o piernas"
label var QD333_5 "Alguna dificultad o limitación permanente para entender o aprender (concentrarse y recordarse)"
label var QD333_6 "Alguna dificultad o limitación permanente para relacionarse con los demás, por sus pensamientos, sentimientos, emociones o conductas"
label var V190 "Índice de riqueza"
label define V190 1 "Quintil_inferior" 2 "Segundo_quintil" 3 "Quintil_intermedio" ///
4 "Cuarto_quintil" 5 "Quintil_superior"
label values V190 V190
label var AWFACTT "Factor todas las mujeres"
label var AWFACTU "Factor todas las mujeres - urbano/rural"
label var AWFACTR "Factor todas las mujeres - regional"
label var AWFACTE "Factor todas las mujeres - educación"
label var AWFACTW "Factor todas las mujeres - índice de riqueza"
foreach v of var * {
rename `v' `=lower("`v'")'
}
save REC0111.dta, replace
import dbase Modulo66\REC91.dbf, clear
/* contienen información básica sobre el lugar de socialización temprana,
características demográficas, educativas y de acceso a los medios de comunicación
de la entrevistada; información que es de utilidad para entender el contexto
de la reproducción y de la salud y para el cálculo de los indicadores de la situación de la mujer
que sirvan como punto de referencia para la interpretación de los resultados de la ENDES */
label define nosi 0 "No" 1 "Si"
label define SREGION 1 "Lima_Metropolitana" 2 "Resto_Costa" 3 "Sierra" 4 "Selva"
label values SREGION SREGION
label var SREGION "Region Natural"
recode SREGION (1 2=1) (3=2) (4=3), gen(region_natural)
label define region_natural 1 "Costa" 2 "Sierra" 3 "Selva"
label values region_natural region_natural
label var CASEID "Identificacion Cuestionario Individual"
label var S108N "Nivel educativo aprobado"
label var S111 "Actualmente asiste a la escuela, colegio, instituto o universidad"
label var S112 "Razón por que dejo de asistir a la escuela"
label define S112 1 "Quedó embarazada" 2 "Se casó/se unió" ///
3 "Tenía que cuidar a las niños más pequeños" ///
4 "Tenìa que ayudar en la chacra o negocio de la familia" 5 "Falta de dinero" ///
6 "Enfermedad" 7 "Necesitaba trabajar para ganar dinero" ///
8 "Se graduó/suficiente estudio" 9 "No aprobó examen de ingreso" ///
10 "No quiso estudiar" 11 "Escuela muy lejos/no había escuela" ///
12 "No había maestros en la escuela" 13 "Estudia en academia preuni./carrera corta" ///
96 "Otra" 98 "No sabe"
label values S112 S112
label var S119 "Idioma o lengua materna que aprendió hablar en su niñez"
recode S119 (10=1) (1/9=2) (11 12=3), gen(lmaterna)
label define lmaterna 1 "Castellano" 2 "Lengua nativa 4/" 3 "Extranjera"
label values lmaterna lmaterna
label var lmaterna "Lengua Materna"
label var S119NA "Idioma materna su madre"
label var S119NB "Lengua materna su padre"
label var S119D "Por sus antepasados y costumbres, Ud. Se considera"
label define S119D 1 "Quechua" 2 "Aimara" 3 "Nativo o indigena de la Amazonía" ///
4 "Parte de otro pueblo indigena u originario" 5"Negro/ Moreno/ Zambo/ Mulato/Pueblo Afroperuano o afrodescendiente" ///
6 "Blanco" 7 "Mestizo" 8 "Otro" 98 "No sabe"
label values S119D S119D
recode S119D (1 2 3 4=1) (5=2) (6=3) (7=4) (8 98=5), gen(etnia)
label define etnia 1 "Origen nativo 2/" 2"Negro, moreno, zambo 3/" 3 "Blanco" 4 "Mestizo" 5 "Otro/ No sabe"
label values etnia etnia
label var S229B1 "Afiliada a seguro de salud (seguro integral)"
label var S239F "Documento de identificación: No tiene"
label var S815AA "Conoce la ETS: sífilis"
label var S815AB "Conoce la ETS: gonorrea"
label var S815AC "Conoce la ETS: verrugas genitales/condiloma"
label var S815AD "Conoce la ETS: Chancro"
label var S815AE "Conoce la ETS: Herpes"
label var S815AX "Conoce la ETS: Otros"
label var S815AZ "Conoce la ETS: No sabe"
label var S816AA "Síntomas de ETS en mujeres: dolor abdominal"
label var S816AB "Síntomas de ETS en mujeres: secreción genital de flujo por la vagina"
label var S816AC "Síntomas de ETS en mujeres: secreción mal oliente"
label var S816AD "Síntomas de ETS en mujeres: molestias al orinar"
label var S816AE "Síntomas de ETS en mujeres: enrojecimiento/picazón/ardor en genitales"
label var S816AF "Síntomas de ETS en mujeres: inflamación/hinchazón/dolor en genitales"
label var S816AG "Síntomas de ETS en mujeres: úlceras/llagas genitales"
label var S816AH "Síntomas de ETS en mujeres: verrugas genitales"
label var S816AI "Síntomas de ETS en mujeres: sangre en la orina"
label var S816AJ "Síntomas de ETS en mujeres: pérdida de peso"
label var S816AK "Síntomas de ETS en mujeres: infertilidad/no poder tener hijos"
label var S816AL "Síntomas de ETS en mujeres: los síntomas pueden no estar presentes"
label var S816AW "Síntomas de ETS en mujeres: otros"
label var S816AZ "Síntomas de ETS en mujeres: no sabe"
label var S817 "Le han Diagnosticado alguna ETS en los últimos 12 meses"
label values S815A* S816A* nosi
foreach v of var * {
rename `v' `=lower("`v'")'
}
save REC91.dta, replace
import dbase Modulo67\REC21.dbf, clear
label var CASEID "Identificacion Cuestionario Individual"
label var BIDX "Número de orden de nacimiento"
label var BORD "Número de orden en la historia de nacimiento"
label var B3 "Fecha de nacimiento, Codificación centenaria de meses (CMC)"
label var B4 "Sexo del niño"
label define B4 1 "Hombre" 2 "Mujer"
label values B4 B4
label var B5 "Nihno esta vivo"
label var B7 "Edad a la muerte (meses-imputado)"
label var B9 "Con quien vive el niño"
label define B9 0 "Entrevistada" 1 "Padre" 2 "Otro pariente" 3 "Alguien más" 4 "Vive en otro lugar"
label values B9 B9
label var QD333_1 "Alg. dificultad o limitacion ver"
label var QD333_2 "Alg. dificultad o limitacion oir, aún usando audífonos"
label var QD333_3 "Alg. dificultad o limitacion hablar o comunicarse"
label var QD333_4 "Alg. dificultad o limitacion moverse o caminar para usar brazos y/o piernas"
label var QD333_5 "Alg. dificultad o limitacion entender o aprender"
label var QD333_6 "Alg. dificultad o limitacion relacionarse con los demás"
rename BIDX MIDX
sort CASEID MIDX
foreach v of var * {
rename `v' `=lower("`v'")'
}
save REC21.dta, replace
import dbase Modulo70\REC43.dbf, clear
label define vacuna 0 "No" 1 "Vacuna fecha en la tarjeta" 2 "Reportado por la madre" ///
3 "Vacuna marcado en la tarjeta" 8 "No sabe"
label var CASEID "Identificación Cuestionario Individual"
label var HIDX "Nro. orden de historia de nacimiento"
label var H0 "Recibió vacuna POLIO 0"
label var H1 "Tiene el carné de atención integral de la niña(o)"
label var H2 "Recibió vacuna BCG"
label var H3 "Recibió vacuna DPT 1ra. dosis"
label var H4 "Recibió vacuna POLIO 1ra. dosis"
label var H5 "Recibió vacuna DPT 2da. dosis"
label var H6 "Recibió vacuna POLIO 2da. dosis"
label var H7 "Recibió vacuna DPT 3ra. dosis"
label var H8 "Recibió vacuna POLIO 3ra. dosis"
label values H0 H1 H2 H3 H4 H5 H6 H7 H8 vacuna
label var H11 "En los últimos 14 dìas, ha tenido diarrea la niña(o)"
label define nosi 0 "No" 1 "Sí, las últimas 24 horas" 2 "Sí, las últimas dos semanas" 8 "No sabe"
label values H11 nosi
label var H31 "Ha tenido tos en las últimas dos semanas"
label values H31 nosi
label var H31B "Cuando estuvo enfermo con tos, respiraba más rápido con respiraciones cortas y rápidas"
label var H31C "La respiración rápida o difícil era por un problema en el pecho o porque tenía la nariz tupida"
label var H33D "Vitamina A1 día"
label var H33M "Vitamina A1 mes"
label var H33Y "Vitamina A1 año"
label var H34 "Vitamina A en los últimos 6 meses"
label var H42 "Tomando píldoras de hierro, jarabe"
label var H43 "Medicamentos para parásitos intestinales en los últimos 6 meses"
rename HIDX MIDX
foreach v of var * {
rename `v' `=lower("`v'")'
}
save REC43.dta, replace
import dbase Modulo70\REC95.dbf, clear
label var CASEID "Identificación Cuestionario Individual"
label var IDX95 "Índice de historia de nacimiento"
label var S45D4 "Recibió 1er. refuerzo DPT"
label var S45P4 "Recibió 1er. refuerzo Polio"
label var S465EA "En los últimos 7 días tomo hierro en jarabe"
label var S465EB "En los Últimos 7 días tomo hierro en polvo como Micronutrientes"
label var S465EC "En los Últimos 7 días tomo hierro en gotas"
label var S465ED "En los Últimos 7 día tomo hierro en otra presentación"
label var S466 "Le hicieron algún control de crecimiento y desarrollo"
label var S466B "Dónde le realizaron el control de crecimiento y desarrollo"
label var S466C "Cantidad de controles de crecimiento de control"
label var S466DC1 "Día - Control 1"
label var S470 "Por qué no acudió a un centro de salud cuando estuvo enfermo con fiebre/tos"
label var Q452 "Número de orden en la historia de nacimiento"
rename IDX95 MIDX
sort CASEID MIDX
foreach v of var * {
rename `v' `=lower("`v'")'
}
save REC95.dta, replace
use rec21, clear
merge 1:1 caseid midx using "rec43", nogen
merge 1:1 caseid midx using "rec95", nogen
save rec21_rec43_rec95.dta, replace
use rec0111, clear
merge 1:1 caseid using "rec91", nogen
save rec0111_rec91.dta, replace
merge 1:m caseid using "rec21_rec43_rec95", nogen
*Factor de expansion
gen wt=v005/1000000
*Edad
gen age=v008-b3
gen age6_59=age>5 & age<60
gen age6_35=age>5 & age<36
*Nivel de educacion de la madre
recode v106 (0 1=1 "Sin_nivel_Primaria")(2=2 "Secundaria") (3=3 "Superior"), gen(edumadre)
*Creamos etiqueta para los valores de las variables
label define sino 1 "Si" 0 "No"
//Recibió medicamento desparasitante en los últimos 12 meses
gen nt_ch_micro_dwm= h43==1
replace nt_ch_micro_dwm=. if b5==0
label values nt_ch_micro_dwm sino
label var nt_ch_micro_dwm "Recibió medicamento desparasitante en los últimos 12 meses"
//Recibió suplementos de hierro en los últimos 7 días 3/
gen nt_ch_micro_iron= s465ea==1 | s465eb==1 | s465ec==1 | s465ed==1
replace nt_ch_micro_iron=. if b5==0
label values nt_ch_micro_iron sino
label var nt_ch_micro_iron "Recibió suplementos de hierro en los últimos 7 días 3/"
*Niñas y niños de 6 a 59 meses de edad
*Desparasitante
tab v025 nt_ch_micro_dwm [iweight=wt] if v012>14 & age6_59==1, nofreq row
tab sregion nt_ch_micro_dwm [iweight=wt] if v012>14 & age6_59==1, nofreq row
*Hierro
tab v025 nt_ch_micro_iron [iweight=wt] if v012>14 & age6_59==1 & b9==0, nofreq row
tab sregion nt_ch_micro_iron [iweight=wt] if v012>14 & age6_59==1 & b9==0, nofreq row
*Niñas y niños de 6 a 35 meses de edad
*Hierro
tab v025 nt_ch_micro_iron [iweight=wt] if v012>14 & age6_35==1 & b9==0, nofreq row
tab sregion nt_ch_micro_iron [iweight=wt] if v012>14 & age6_35==1 & b9==0, nofreq row
tab edumadre nt_ch_micro_iron [iweight=wt] if v012>14 & age6_35==1 & b9==0, nofreq row
Comentarios
Publicar un comentario