Hola a tod@s, comparto la sintaxis para estimar estadísticas de la primera relación sexual en mujeres de 12 a 24 años de edad usando la Encuesta Demográfica y de Salud Familiar (ENDES) del 2019 en STATA.
Janet Porras
********
*Especificamos nuestra carpeta de trabajo
cd "E:\ENDES"
*Bajamos y descomprimimos los modulos 66 & 72
import dbase Modulo66\REC0111.dbf, clear
label define V015 1 "Completa" 2 "Ausente" 3 "Aplazada" 4 "Rechazada" ///
5 "Respondida parcialmente" 6 "Incapacitada" 7 "Otra"
label values V015 V015
label var V015 "Resultado de entrevista individual"
label var HHID "Identificacion Cuestionario del Hogar"
label var CASEID "Identificacion Cuestionario Individual"
label var V012 "Edad actual -Age in single years"
label var V013 "Edad actual por grupos de 5 años"
label define V013 0 "12 a 14 años" 1"15 a 19 años" 2"20 a 24 años" 3"25 a 29 años" ///
4"30 a 34 años" 5"35 a 39 años" 6"40 a 44 años" 7"45 a 49 años"
label values V013 V013
recode V013 (0=0) (1=1) (2 3=2) (4 5=3) (6 7=4), gen(gedad)
label define gedad 0 "12 a 14 años" 1"15 a 19 años" ///
2"20 a 29 años" 3"30 a 39 años" 4"40 a 49 años"
label values gedad gedad
label var V001 "Conglomerado"
label var V002 "Número de vivienda"
label var V003 "Número de línea de entrevistada"
label var V005 "Factor de ponderación mujer"
label var V008 "Fecha de la entrevista, Codificación centenaria de meses (CMC)"
label var V011 "Fecha de nacimiento, Codificación centenaria de meses (CMC)"
label var V021 "Unidad de muestreo primario - conglomerado"
label var V022 "Estratos"
label var V024 "Región"
label var V025 "Tipo de lugar de residencia"
label define V025 1 "Urbano" 2 "Rural"
label values V025 V025
label var V042 "Selección de hogar para hemoglobina"
label var V043 "Selección para módulo de estatus de mujeres"
label var V044 "Selección para módulo de violencia domestica"
label var V101 "Región"
label var V102 "Tipo de lugar de residencia"
label var V106 "Nivel educativo más alto"
label define V106 0 "Sin educación" 1 "Primaria" 2 "Secundaria" 3 "Superior"
label values V106 V106
label var V129 "Material predominante del techo de la vivienda"
label var V133 "Educación en años simples"
label var V135 "Residente habitual o visitante"
label var V149 "Logro educativo"
label define V149 0 "Sin educación" 1 "Primaria incompleta" 2 "Primaria completa" ///
3 "Secundaria incompleta" 4 "Secundaria completa" 5 "Superior"
label values V149 V149
label var V155 "Alfabetización"
label define V155 0 "No puede leer" 1 "Puede leer sólo parte de la frase" ///
2 "Puede leer la frase" 3 "No hay tarjeta en el idioma requerido" ///
4 "Ciega/problemas visuales"
label values V155 V155
label var QD333_1 "Alguna dificultad/limitación permanente para ver, aún usando anteojos"
label var QD333_2 "Alguna dificultad/limitación permanente para oir, aún usando audífonos"
label var QD333_3 "Alguna dificultad/limitación permanente para hablar o comunicarse, aún usando la lengua de señas u otro"
label var QD333_4 "Alguna dificultad/limitación permanente para moverse o caminar para usar brazos y/o piernas"
label var QD333_5 "Alguna dificultad o limitación permanente para entender o aprender (concentrarse y recordarse)"
label var QD333_6 "Alguna dificultad o limitación permanente para relacionarse con los demás, por sus pensamientos, sentimientos, emociones o conductas"
label var V190 "Índice de riqueza"
label define V190 1 "Quintil_inferior" 2 "Segundo_quintil" 3 "Quintil_intermedio" ///
4 "Cuarto_quintil" 5 "Quintil_superior"
label values V190 V190
label var AWFACTT "Factor todas las mujeres"
label var AWFACTU "Factor todas las mujeres - urbano/rural"
label var AWFACTR "Factor todas las mujeres - regional"
label var AWFACTE "Factor todas las mujeres - educación"
label var AWFACTW "Factor todas las mujeres - índice de riqueza"
foreach v of var * {
rename `v' `=lower("`v'")'
}
save REC0111.dta, replace
import dbase Modulo66\REC91.dbf, clear
label define nosi 0 "No" 1 "Si"
label define SREGION 1 "Lima_Metropolitana" 2 "Resto_Costa" 3 "Sierra" 4 "Selva"
label values SREGION SREGION
label var SREGION "Region Natural"
recode SREGION (1 2=1) (3=2) (4=3), gen(region_natural)
label define region_natural 1 "Costa" 2 "Sierra" 3 "Selva"
label values region_natural region_natural
label var CASEID "Identificacion Cuestionario Individual"
label var S108N "Nivel educativo aprobado"
label var S111 "Actualmente asiste a la escuela, colegio, instituto o universidad"
label var S112 "Razón por que dejo de asistir a la escuela"
label define S112 1 "Quedó embarazada" 2 "Se casó/se unió" ///
3 "Tenía que cuidar a las niños más pequeños" ///
4 "Tenìa que ayudar en la chacra o negocio de la familia" 5 "Falta de dinero" ///
6 "Enfermedad" 7 "Necesitaba trabajar para ganar dinero" ///
8 "Se graduó/suficiente estudio" 9 "No aprobó examen de ingreso" ///
10 "No quiso estudiar" 11 "Escuela muy lejos/no había escuela" ///
12 "No había maestros en la escuela" 13 "Estudia en academia preuni./carrera corta" ///
96 "Otra" 98 "No sabe"
label values S112 S112
label var S119 "Idioma o lengua materna que aprendió hablar en su niñez"
recode S119 (10=1) (1/9=2) (11 12=3), gen(lmaterna)
label define lmaterna 1 "Castellano" 2 "Lengua nativa 4/" 3 "Extranjera"
label values lmaterna lmaterna
label var lmaterna "Lengua Materna"
label var S119NA "Idioma materna su madre"
label var S119NB "Lengua materna su padre"
label var S119D "Por sus antepasados y costumbres, Ud. Se considera"
label define S119D 1 "Quechua" 2 "Aimara" 3 "Nativo o indigena de la Amazonía" ///
4 "Parte de otro pueblo indigena u originario" 5"Negro/ Moreno/ Zambo/ Mulato/Pueblo Afroperuano o afrodescendiente" ///
6 "Blanco" 7 "Mestizo" 8 "Otro" 98 "No sabe"
label values S119D S119D
recode S119D (1 2 3 4=1) (5=2) (6=3) (7=4) (8 98=5), gen(etnia)
label define etnia 1 "Origen nativo 2/" 2"Negro, moreno, zambo 3/" 3 "Blanco" 4 "Mestizo" 5 "Otro/ No sabe"
label values etnia etnia
label var S229B1 "Afiliada a seguro de salud (seguro integral)"
label var S239F "Documento de identificación: No tiene"
label var S815AA "Conoce la ETS: sífilis"
label var S815AB "Conoce la ETS: gonorrea"
label var S815AC "Conoce la ETS: verrugas genitales/condiloma"
label var S815AD "Conoce la ETS: Chancro"
label var S815AE "Conoce la ETS: Herpes"
label var S815AX "Conoce la ETS: Otros"
label var S815AZ "Conoce la ETS: No sabe"
label var S816AA "Síntomas de ETS en mujeres: dolor abdominal"
label var S816AB "Síntomas de ETS en mujeres: secreción genital de flujo por la vagina"
label var S816AC "Síntomas de ETS en mujeres: secreción mal oliente"
label var S816AD "Síntomas de ETS en mujeres: molestias al orinar"
label var S816AE "Síntomas de ETS en mujeres: enrojecimiento/picazón/ardor en genitales"
label var S816AF "Síntomas de ETS en mujeres: inflamación/hinchazón/dolor en genitales"
label var S816AG "Síntomas de ETS en mujeres: úlceras/llagas genitales"
label var S816AH "Síntomas de ETS en mujeres: verrugas genitales"
label var S816AI "Síntomas de ETS en mujeres: sangre en la orina"
label var S816AJ "Síntomas de ETS en mujeres: pérdida de peso"
label var S816AK "Síntomas de ETS en mujeres: infertilidad/no poder tener hijos"
label var S816AL "Síntomas de ETS en mujeres: los síntomas pueden no estar presentes"
label var S816AW "Síntomas de ETS en mujeres: otros"
label var S816AZ "Síntomas de ETS en mujeres: no sabe"
label var S817 "Le han Diagnosticado alguna ETS en los últimos 12 meses"
label values S815A* S816A* nosi
foreach v of var * {
rename `v' `=lower("`v'")'
}
save REC91.dta, replace
import dbase "Modulo72\RE758081.dbf", clear
label var CASEID "Identificacion Cuestionario Individual"
label var V751 "Ha oído hablar de una enfermedad llamada SIDA"
label var V754BP "Cree usted que las personas que no tienen relaciones sexuales tienen menos riesgo de adquirir el virus del VIH"
label var V754CP "Cree usted que las personas que usan condón cada vez que tienen relaciones sexuales,tienen menos riesgo de adquirir el virus del VIH"
label var V754DP "Cree usted que las personas tienen menos riesgo de adquirir el virus del VIH si tienen una sola tener una pareja sexual que no este infectado y que no tenga otras parejas"
label var V756 "Es posible que una persona que parece saludable este infectada con el virus del VIH"
label var V763A "En los últimos 12 meses, le han diagnosticado alguna ETS"
label var V763B "En los últimos 12 meses, ha tenido alguna llaga o úlceras en sus genitales"
label var V763C "En los últimos 12 meses, ha tenido algùn flujo o secreción genital que olia mal"
label var V763D "Los últimos 12 meses tuvieron ETS"
label var V763E "Los últimos 12 meses tuvieron ETS"
label var V763F "Los últimos 12 meses tuvieron ETS"
label var V763G "Los últimos 12 meses tuvieron ETS"
label define V767 1 "Esposo/conviviente" 2 "Novio/prometido" 3 "Amigo" ///
4 "Compañero casual" 5 "Pariente" 6 "Trabajador sexual" 8 "Enamorado" 96 "Otro"
label var V767A "Relación con la última pareja sexual"
label var V767B "Relación con otra pareja sexual (penúltima)"
label var V767C "Relación con otra pareja sexual (antepenùltima)"
label values V767A V767B V767C V767
label var V774A "En qué etapa la madre con SIDA podría infectar a su hijo: embarazo"
label var V774B "En qué etapa la madre con SIDA podría infectar a su hijo: parto"
label var V774C "En qué etapa la madre con SIDA podría infectar a su hijo: lactancia"
label var V785 "Ha oído hablar de otras enfermedades de transmisión sexual"
label var V820 "En su primera relación sexual usaron condón"
label var V830 "Edad de la primera pareja sexual"
label var V836 "Con cuantos hombres ha tenido relaciones sexuales (últimos 12 meses)"
foreach v of var * {
rename `v' `=lower("`v'")'
}
save RE758081.dta, replace
use rec0111, clear
merge 1:1 caseid using "rec91", nogen
merge 1:1 caseid using "re758081", nogen
/*
V012 Edad actual
V013 Edad actual por grupos de 5 años
V820 En su primera relación sexual usaron condón
V830 Edad de la primera pareja sexual
*/
*Factor de expansion
gen wt=v005/1000000
//Uso Condon
recode v820 (0 8=2 "No/No sabe")(1=1 "Si"),gen(uso_condon)
tab v013 uso_condon if v012<25
tab v013 uso_condon [iweight=wt] if v012<25, nofreq row
tab v025 uso_condon [iweight=wt] if v012<25, nofreq row
tab sregion uso_condon [iweight=wt] if v012<25, nofreq row
//Edad de la persona con la que tuvo relaciones
recode v830 (12/19 =1 "<20")(20/24=2 "20-24")(98=4 "No sabe")(nonmiss=3 ">24"),gen(edad_persona)
tab v013 edad_persona if v012<25
tab v013 edad_persona [iweight=wt] if v012<25, nofreq row
tab v025 edad_persona [iweight=wt] if v012<25, nofreq row
tab sregion edad_persona [iweight=wt] if v012<25, nofreq row
Comentarios
Publicar un comentario